This is an archived, read-only copy of the United-TI subforum , including posts and topic from May 2003 to April 2012. If you would like to discuss any of the topics in this forum, you can visit Cemetech's TI-BASIC subforum. Some of these topics may also be directly-linked to active Cemetech topics. If you are a Cemetech member with a linked United-TI account, you can link United-TI topics here with your current Cemetech topics.

This forum is locked: you cannot post, reply to, or edit topics. TI-Basic => TI-BASIC
United-TI Archives -> TI-Basic
 
    » Goto page Previous  1, 2, 3, 4, 5, 6  Next
» View previous topic :: View next topic  
Author Message
kalan_vod


Advanced Member


Joined: 04 Sep 2005
Posts: 446

Posted: 11 Sep 2007 04:00:57 pm    Post subject:

I mean I was not trying to make fun, but there is some serious thinking out of the box to be done with this program (he could have).
Back to top
DarkerLine
ceci n'est pas une |


Super Elite (Last Title)


Joined: 04 Nov 2003
Posts: 8328

Posted: 11 Sep 2007 04:22:08 pm    Post subject:

What that code needs is rewriting from scratch. With that in mind, here's code I still wouldn't consider a good hangman game because, for one, there's no picture of a hangman and no other indication of how close you are to losing.

:"ABCDEFGHIJKLMNOPQRSTUVWXYZ→Str0

:Repeat length(Str1)<33
:ClrHome
:Disp "WORD? (32 CHARS)"
:Input "",Str1
:End

:"space→Str2
:For(I,1,length(Str1
:sub(Str1,I,1
:If inString(Str0,Ans:"-
:Str2+Ans→Str2
:End
:Ans+" →Str2
:"space"+Str1+"space→Str1

:DelVar TRepeat Str1=Str2 or T=12 edit for difficulty
:Output(1,1,Str2

:Repeat 30<Ans and Ans<94
:getKey
:If Ans=45:Goto Q
:End
:Ans-20-5int(.1Ans)-2(Ans>45→K
:sub(Str0,Ans,1→Str3
:Output(4+(K>16),17fPart(K/17,Ans

:inString(Str1,Ans→I
:T+not(Ans→T
:While I
:sub(Str2,1,Ans-1)+Str3+sub(Str2,Ans+1,length(Str2)-Ans→Str2
:inString(Str1,Str3,I+1→I
:End

:End

:Lbl Q
:ClrHome
:"YOU "+sub("WIN!!LOSE!",6-5(Str1=Str2),5


Last edited by Guest on 24 Sep 2010 04:00:48 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 11 Sep 2007 05:35:01 pm    Post subject:

Maybe what you could do is tie the number of tries to the length of the word. So, if the word is apples, then you would get six chances to guess it. Does that work any better?

P.S. I believe the Str0 in :Repeat length(Str0)<=32 is supposed to be Str1.


Last edited by Guest on 24 Sep 2010 04:01:19 pm; edited 1 time in total
Back to top
DarkerLine
ceci n'est pas une |


Super Elite (Last Title)


Joined: 04 Nov 2003
Posts: 8328

Posted: 11 Sep 2007 05:44:41 pm    Post subject:

spandiv wrote:
Maybe what you could do is tie the number of tries to the length of the word. So, if the word is apples, then you would get six chances to guess it. Does that work any better?

But it's harder to guess a short word than a long one! If the word (or phrase) is long, that makes it more likely that any given letter will actually be in it, and you're also more likely to recognize the word early on.

Quote:
P.S. I believe the Str0 in :Repeat length(Str0)<=32 is supposed to be Str1.
[post="112530"]<{POST_SNAPBACK}>[/post]
Fixed. Also stopped the number of guesses from going down even if you guess correctly - this shouldn't happen in hangman.

Last edited by Guest on 24 Sep 2010 04:01:54 pm; edited 1 time in total
Back to top
kalan_vod


Advanced Member


Joined: 04 Sep 2005
Posts: 446

Posted: 11 Sep 2007 05:58:58 pm    Post subject:

DarkerLine wrote:
:Ans-20-5int(.1Ans)-2(Ans>45→K

Is going to error if Ans<1 or Ans>27, might add in repeat.


Last edited by Guest on 11 Sep 2007 05:59:33 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 11 Sep 2007 06:12:49 pm    Post subject:

kalan_vod wrote:
DarkerLine wrote:
:Ans-20-5int(.1Ans)-2(Ans>45→K
Is going to error if Ans<1 or Ans>27, might add in repeat.
If you're going to add error checking for that, you should add error checking for when the user inputs the word at the beginning. Right now, the user could have a word consisting of a command or theta or whatever. Personally, I would just leave off error checking. I think the code looks more elegant that way.

Last edited by Guest on 11 Sep 2007 06:35:35 pm; edited 1 time in total
Back to top
DarkerLine
ceci n'est pas une |


Super Elite (Last Title)


Joined: 04 Nov 2003
Posts: 8328

Posted: 11 Sep 2007 06:35:54 pm    Post subject:

Anyways, I added the error checking for both of those things, I think it doesn't look that bad. Actually, this way any non-uppercase-letter token is treated the same as a space, and entering "sin(THETA)" as the word will have the other person guessing "sin(-----)".

Last edited by Guest on 11 Sep 2007 06:38:02 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 12 Sep 2007 12:45:05 am    Post subject:

When I tried out the program, I saw a few changes that you can make:

  • :Repeat length(Str1)<33
    can be
    :Repeat 33>length(Str1


  • :" →Str2
    :For(I,1,length(Str1
    :sub(Str1,I,1
    :If inString(Str0,Ans:"-
    :Str2+Ans→Str2
    :End
    :Ans+" →Str2
    :"space"+Str1+"space→Str1

    can be
    :"?
    :For(I,1,length(Str1
    :If inString(Str0,sub(Str1,I,1
    :Ans+"-
    :End
    :sub(Ans,2,length(Ans)-1→Str2


  • :DelVar TRepeat Str1=Str2 or T=12
    can be
    12→T:While Str1≠Str2 and T


  • :Output(4+(K>16),17fPart(K/17,Ans
    needs to be
    :Output(4+(K>16),round(17fPart(K/17)),Ans


  • :sub(Str2,1,Ans-1)+Str3+sub(Str2,Ans+1,length(Str2)-Ans→Str2
    needs to be
    :sub(sub(" "+Str2,1,I-1)+Str3+sub(Str2+" ",I+1,length(Str2)-I+1),2,length(Str2)→Str2


  • :"YOU "+sub("WIN!!LOSE!",6-5(Str1=Str2),5
    can be
    :"YOU "+sub("WIN! LOSE!",1+5not(T),5

The one other change I would make is to add a ClrHome before the main game loop,
because it looks kind of sloppy to just write over the "WORD? (32 CHARS)" text.


Last edited by Guest on 24 Sep 2010 04:02:27 pm; edited 1 time in total
Back to top
DarkerLine
ceci n'est pas une |


Super Elite (Last Title)


Joined: 04 Nov 2003
Posts: 8328

Posted: 12 Sep 2007 08:37:28 am    Post subject:

Quote:
:Output(4+(K>16),17fPart(K/17,Ans
needs to be
:Output(4+(K>16),round(17fPart(K/17)),Ans
Darn. In that case, how about K-16(K>16)?

Last edited by Guest on 24 Sep 2010 04:02:56 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 12 Sep 2007 03:43:36 pm    Post subject:

So, here's what the program looks like right now:

:"ABCDEFGHIJKLMNOPQRSTUVWXYZ→Str0
:{6.9,6.7,5.8,4.9,4.7,4.8,3.8→L1
:Repeat 33>length(Str1
:ClrHome
:Disp "WORD? (32 CHARS)"
:Input "",Str1
:End
:"space
:For(I,1,length(Str1
:If inString(Str0,sub(Str1,I,1
:Ans+"-
:End
:sub(Ans,2,length(Ans)-1→Str2
:dim(L1→T
:ClrHome
:While Str1≠Str2 and T
:Output(1,1,Str2
:Repeat 30<Ans and Ans<94
:getKey
:End
:If Ans=45:Goto Q
:Ans-20-5int(.1Ans)-2(Ans>45→K
:sub(Str0,Ans,1→Str3
:Output(7+(K>14),K+1-13(K>14),Ans
:inString(Str1,Ans→I
:If I:Then
:While I
:sub(sub(" "+Str2,1,I-1)+Str3+sub(Str2+" ",I+1,length(Str2)-I+1),2,length(Str2)→Str2
:inString(Str1,Str3,I+1→I
:End
:Else
:Output(iPart(L1(T)),10fPart(L1(T)),sub("^^I--IO",T,1
:T-1→T
:End
:End
:Lbl Q
:Pause "YOU "+sub("LOSE!WIN! ",1+5(Str1=Str2),5
:ClrHome


Last edited by Guest on 24 Sep 2010 04:03:12 pm; edited 1 time in total
Back to top
DarkerLine
ceci n'est pas une |


Super Elite (Last Title)


Joined: 04 Nov 2003
Posts: 8328

Posted: 12 Sep 2007 05:31:02 pm    Post subject:

A few more improvements. Also, one of your optimizations (in the initialize-Str2 loop) I just realized doesn't actually work when the word to be guessed is actually a phrase.
:"ABCDEFGHIJKLMNOPQRSTUVWXYZ→Str0
:Repeat 33>length(Str1
:ClrHome
:Disp "WORD? (32 CHARS)
:Input "",Str1
:End
:"?→Str2
:For(I,1,length(Str1
:sub(Str1,I,1
:If inString(Str0,Ans:"-
:Str2+Ans→Str2
:End

:sub(Ans,2,length(Ans)-1→Str2
:8→T
:ClrHome
:While Str1≠Str2 and T
:Output(1,1,Str2
:.1{69,67,58,49,47,48,38,38
:Output(iPart(Ans(T)),10fPart(Ans(T)),sub("^^I--IO ",T,1

:Repeat 30<Ans and Ans<94
:getKey
:End
:If Ans=45:Goto Q
:Ans-20-5int(.1Ans)-2(Ans>45→K
:sub(Str0,Ans,1→Str3
:Output(7+(K>14),K+1-13(K>14),Ans
:inString(Str1,Ans→I
:T-not(Ans→T
:While I
:sub(sub(" "+Str2,1,I)+Str3+sub(Str2+" ",I+1,length(Str2)-I+1),2,length(Str2)→Str2
:inString(Str1,Str3,I+1→I
:End
:End
:Lbl Q
:Pause "YOU "+sub("LOSE!WIN! ",1+5(Str1=Str2),5
:ClrHome


Last edited by Guest on 24 Sep 2010 04:03:34 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 12 Sep 2007 05:45:48 pm    Post subject:

The calculator should crash on this line:

:sub(sub(" "+Str2,1,I-1)+Str3+sub(Str2+" ",I+1,length(Str2)-I+1),2,length(Str2)→Str2

When I copied the program from my calculator to the post, I somehow added a -1 to the second sub( command. The correct line is:

:sub(sub(" "+Str2,1,I)+Str3+sub(Str2+" ",I+1,length(Str2)-I+1),2,length(Str2)→Str2

Sorry about the mistake.

The program looks pretty optimized to me. Who wants to come up with the next program?


Last edited by Guest on 24 Sep 2010 04:03:57 pm; edited 1 time in total
Back to top
simplethinker
snjwffl


Active Member


Joined: 25 Jul 2006
Posts: 700

Posted: 12 Sep 2007 08:43:00 pm    Post subject:

Ok, so the final tally
Original: 2,442 bytes
New:444 bytes
Saved:1998 bytes
New program is 18.2% of what it was

here it is: [attachment=1892:attachment]

[edit] okay, okay, it's 444 instead of 44, but doesn't cutting a 2,442 byte program to 44 bytes look good?


Last edited by Guest on 12 Sep 2007 09:41:32 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 12 Sep 2007 09:38:01 pm    Post subject:

simplethinker wrote:
Ok, so the final tally
Original: 2,442 bytes
New:44 bytes
Saved:1998 bytes
New program is 18.2% of what it was
I think you mean the new program is 444 bytes. I guess we can move on to the next program then.

EDIT: I like the idea of seeing the before and after in terms of program size, so here are the results for the Frogger program:

Original: 1,622 bytes
New: 807 bytes
Saved: 815 bytes (50.2% of program removed)


Last edited by Guest on 12 Sep 2007 10:07:45 pm; edited 1 time in total
Back to top
Demon


Advanced Member


Joined: 17 Jun 2006
Posts: 369

Posted: 12 Sep 2007 11:06:31 pm    Post subject:

Now if only TIOS had a compressed filesystem it could be even smaller...
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 12 Sep 2007 11:53:25 pm    Post subject:

For the next program, I decided to go with a game that uses the graph screen rather than the home screen. Don't worry, though, the code is still pretty crappy :D

Paper Football -- http://www.ticalc.org/archives/files/fileinfo/117/11712.html


Code:
[goose]:ClrDraw
:ClrHome
:Output(4,2,"D. JacKaL")
:Output(5,7," SOFTWARE")
:Output(1,1,"****************"
:Output(8,1,"****PRESENTS****"
:Pause
:ClrHome
:Output(1,1,"****************
:Output(8,1,"****************
:Output(4,1,"A GAME PORTED BYKAIVAN  KHOSHROO
:Pause :ClrHome
:Lbl 0:FnOff
:ZStandard:Full:17→W:1→X:AxesOff:0→S:0→T
:-6→Xmin:14→Xmax:Line(-5,10,-5,-2
:Line(5,10,5,-2
:Line(-3.8,10,-3.8,-1
:Line(4,10,4,-1
:Line(4,-1,-3.8,-1
:Line(5,-2,-5,-2
:Line(.5,-2,.5,-10
:Line(-.5,-2,-.5,-10
:Text(12,12,"PRESS  2ND
:Text(18,14,"TO LEAVE
:Text(41,36,"FOOTBALL
:Text(48,36,"VERSION 4.0
:Text(54,36,"BY D. JacKaL, KK
:Text(0,56,"---------
:Text(12,56,"---------
:Text(6,55,"ENTER TIME
:Text(25,55,"(<-)=SHORT
:Text(31,55,"(->)=LONG
:10→θ
:Repeat K=105 or K=21
:Text(18,70,θ
:getKey→K
:If K=24 and θ>10:θ-10→θ
:If K=26 and θ<90:θ+10→θ
:End
:ZStandard
:If K=21:Then
:Disp "THANK YOU FOR
:Disp "PLAYING FOOTBALL
:Stop:End
:round(rand*2,0)+1→Y
:Line(-9,10,-9,0
:Line(9,10,9,0
:Line(9,8,9,2,0
:Line(-9,8,-9,2,0
:Line(7,10,7,0
:Line(-7,10,-7,0
:Line(7,8,7,2,0
:Line(-7,8,-7,2,0
:Line(-10,10,-10,-10
:Line(-10,-10,10,-10
:Line(10,-10,10,10
:Line(10,10,-10,10
:Line(10,10,10,-10
:Line(-10,0,10,0
:Line(.5,0,.5,-10
:Line(-.5,0,-.5,-10
:Text(33,4,"PLAYER = 1
:Text(47,4,"PLAYER = 2"
:Text(33,55,"CONDITION
:If Y=1
:Text(39,66," ICE"
:If Y=3
:Text(39,59,"NORMAL"
:If Y=2:Then
:5→Y:Text(39,59,"  ROCKY"):End
:Text(47,53,"FLICKS LEFT
:Text(53,56,"FLICKS=          "
:Lbl M
:Text(39,6,"SCORE=",S
:Text(53,6,"SCORE=",T
:Text(53,83,"         
:Text(53,83,θ
:For(M,32,61,6
:Text(M,46,"   
:End
:If θ=0:Goto Q
:If X=1:Then
:W-6→B
:Pxl-On(20,B-4
:Pxl-On(14,B-2
:Pxl-On(15,B-3
:Pxl-On(15,B-1
:Pxl-On(16,B
:Pxl-On(18,B
:Pxl-On(20,B
:Pxl-On(21,B-1
:Pxl-On(21,B-2
:Pxl-On(21,B-3
:Pxl-On(21,B-1
:Pxl-On(19,B-1
:Pxl-On(17,B-1
:End
:If X=2:Then
:W+6→B
:Pxl-On(20,B+4
:Pxl-On(14,B+2
:Pxl-On(15,B+3
:Pxl-On(15,B+1
:Pxl-On(16,B
:Pxl-On(18,B
:Pxl-On(20,B
:Pxl-On(21,B+1
:Pxl-On(21,B+2
:Pxl-On(21,B+3
:Pxl-On(21,B+1
:Pxl-On(19,B+1
:Pxl-On(17,B+1
:End
:Text(13,W-1,"0
:Pause
:For(C,61,32,-1
:Pxl-Change(C,47
:getKey→K
:If K=105:Goto 2:End
:Lbl 2
:If K≠105:Then
:For(M,32,61,6
:Text(M,46,"   
:End:62→C:End
:62-C→C
:If X=1:Then
:Pxl-Off(16,B
:Pxl-On(15,B
:Pxl-On(17,B
:Pxl-On(15,B+1
:Pxl-On(17,B+1
:Pxl-On(15,B+2
:Pxl-On(17,B+2
:Pxl-On(16,B+3
:End
:If X=2:Then
:Pxl-Off(16,B
:Pxl-On(15,B
:Pxl-On(17,B
:Pxl-On(15,B-1
:Pxl-On(17,B-1
:Pxl-On(15,B-2
:Pxl-On(17,B-2
:Pxl-On(16,B-3
:End
:If X=2:Goto A
:Lbl B:W→D:
:For(D,W,(W+(C*3))-Y*6,2
:Text(13,D-1,"0
:For(M,1,14
:End
:Text(13,D-1,"   
:If D>89:Goto D
:End
:Lbl D
:Text(16,W-10,"       
:Text(14,W-10,"       
:If D>88:Then
:Text(13,25,"ITS WAY PAST!!!
:For(M,1,200
:End
:For(M,25,70,4
:Text(13,M,"   
:End:77→D:End
:Text(13,D-1,"0
:θ-1→θ:D→W:2→X
:If D>80:Goto θ
:Goto M
:Lbl A:W→D
:For(D,W,(W-(C*3))+Y*6,-2
:Text(13,D-1,"0
:For(M,1,14
:End
:Text(13,D-1,"   
:If D<5:Goto C
:End
:Lbl C
:Text(16,W+3,"         
:Text(14,W+3,"         
:If D<6:Then
:Text(13,25,"ITS WAY PAST!!!
:For(M,1,400
:End
:For(M,25,70,4
:Text(13,M,"   
:End:17→D:End
:Text(13,D-1,"0
:1→X:θ-1→θ:D→W
:If D>13:Goto M
:Lbl θ
:Text(15,28,"TOUCHDOWN!!
:For(M,1,300
:End
:Text(14,D-1,"     
:Text(15,28,"                                         
:If X=2:S+6→S
:If X=1:T+6→T
:Text(39,30,S
:Text(53,30,T
:Line(-1,9,-1,7
:Line(1,9,1,7
:Repeat K=105
:For(M,36,56,4
:Text(22,M,"0
:Text(22,M-4,"   
:getKey→K
:If K=105:Goto N
:End
:For(M,56,36,-4
:Text(22,M,"0
:Text(22,M+4,"   
:getKey→K
:If K=105:Goto N
:End:End
:Lbl N:M→N
:For(M,16,4,-6
:Text(M,N,"0
:Text(M+6,N,"   
:If N=40 and M=10 or M=10 and N=52:Goto O
:End
:Lbl O
:If N=44 or N=48:Text(22,32,"ITS GOOD!!
:For(J,1,450
:End
:Text(22,30,"                                 
:If N=40 or N=52
:Text(M,N,"  "
:Text(M+6,N,"  "
:Line(-1,9,-1,7,0
:Line(1,9,1,7,0
:If N=44 or N=48:Then
:If X=2:S+1→S
:If X=1:T+1→T
:End
:If X=2:77→W
:If X=1:17→W
:Goto M
:Lbl Q
:Text(14,D-1,"     
:Text(10,29,"GAME OVER!!
:Text(16,22,"PLAYER-      WINS!!
:If S>T
:Text(16,50,1
:If S<T
:Text(16,50,2
:If S=T
:Text(16,22,"ITS  A  TIE  GAME!!
:Pause :ClrDraw:ClrHome
:Goto 0[/goose]


Last edited by Guest on 24 Sep 2010 04:05:42 pm; edited 1 time in total
Back to top
alexrudd
pm me if you read this


Bandwidth Hog


Joined: 06 Oct 2004
Posts: 2335

Posted: 13 Sep 2007 12:24:58 pm    Post subject:

We need to maintain the credits, I'm guessing? Or are we allowed to remove it since JacKaL software wouldn't recognize the final product at all?

I'll start with this since it's fun to mess around with Ans
:Text(6,55,"ENTER TIME
:Text(25,55,"(<-)=SHORT
:Text(31,55,"(->)=LONG
:10→θ
:Repeat K=105 or K=21
:Text(18,70,θ
:getKey→K
:If K=24 and θ>10:θ-10→θ
:If K=26 and θ<90:θ+10→θ
:End


:Text(6,55,"ENTER TIME
:Text(25,55,"(<-)=SHORT
:Text(31,55,"(->)=LONG
:10→θ
:Repeat Ans=105 or Ans=21 //don't worry, Ans will never be 21 or 105
:Text(18,70,θ
:θ-10((Ans=24 and θ>10)+(Ans=26 and θ<90→θ //or 24 or 26
:getKey K is unnecessary
:End


Last edited by Guest on 24 Sep 2010 04:06:14 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 13 Sep 2007 01:50:17 pm    Post subject:

alexrudd wrote:
We need to maintain the credits, I'm guessing? Or are we allowed to remove it since JacKaL software wouldn't recognize the final product at all?
I actually removed the credits from the Frogger game, since it really just obstructs the gameplay and doesn't add anything. Likewise, the Football game isn't enhanced by the credits.

So, we can get rid of this code right from the get go:

:Output(4,2,"D. JacKaL")
:Output(5,7," SOFTWARE")
:Output(1,1,"****************"
:Output(8,1,"****PRESENTS****"
:Pause
:ClrHome
:Output(1,1,"****************
:Output(8,1,"****************
:Output(4,1,"A GAME PORTED BYKAIVAN KHOSHROO
:Pause :ClrHome


Last edited by Guest on 24 Sep 2010 04:06:32 pm; edited 1 time in total
Back to top
spandiv
-- Retired --


Active Member


Joined: 25 May 2003
Posts: 650

Posted: 19 Sep 2007 12:25:05 am    Post subject:

I've been working on optimizing the Football game tonight, and one of the things I noticed is that the author really likes to jump out of his For( loops with branching. For example, you see several of these code snippets throughout the program:

:For(C,61,32,-1
:Pxl-Change(C,47
:getKey→K
:If K=105:Goto 2:End
:Lbl 2


I'm sure the author probably thought a For( loop worked best because it has the built-in variable declaration and construction, but it really doesn't work very well in this situation. So, I decided to replace the For( loop with a Repeat loop:

:61→C:1→K
:Repeat getKey=105
:K(C≥32 and C≤61)+(C=32)-(C=61→K
:C+Ans→C
:Pxl-Change(Ans,47
:End


I was wondering if anybody else has a better solution, or if this is the best way to go?


Last edited by Guest on 24 Sep 2010 04:06:51 pm; edited 1 time in total
Back to top
Weregoose
Authentic INTJ


Super Elite (Last Title)


Joined: 25 Nov 2004
Posts: 3976

Posted: 19 Sep 2007 12:41:35 am    Post subject:

What about If K=105:32→C ?

Last edited by Guest on 24 Sep 2010 04:00:25 pm; edited 1 time in total
Back to top
Display posts from previous:   
Register to Join the Conversation
Have your own thoughts to add to this or any other topic? Want to ask a question, offer a suggestion, share your own programs and projects, upload a file to the file archives, get help with calculator and computer programming, or simply chat with like-minded coders and tech and calculator enthusiasts via the site-wide AJAX SAX widget? Registration for a free Cemetech account only takes a minute.

» Go to Registration page
    » Goto page Previous  1, 2, 3, 4, 5, 6  Next
» View previous topic :: View next topic  
Page 2 of 6 » All times are UTC - 5 Hours

 

Advertisement