Xmin+ᴇ2∆X<Xmax→|N
StoreGDB GDB1
If |N:BorderColor 4
ClrDraw:AxesOff:FnOff 
PlotsOff :GridOff
If not(FV:Goto θθ
Lbl 00
0→FV
"CALCULUS PROGRAM,1-PRE-CALCULUS,2-LIMITS,3-DIFFERENTIAL,4-INTEGRAL,5-OTHER,6-HELP,7-QUIT
Goto θ1
Lbl θ4
Ans→Str9
Input "NOTE:",Str6
If Str9="1
Str6→|u
If Str9="2
Str6→|v
If Str9="3
Str6→|w
Goto θA
Lbl θ2
Ans→Str1
ClrDraw
1→X:0→A
While X<length(Str1) and A≤54(|N+1
  inString(Str1,"°",X)-X→B
  min({24+7|N,Ans
  Text(A,0,sub(Str1,X,Ans
  X+Ans+(B≤Ans→X:A+6(|N+1→A
End
Repeat getKey:End
Goto θA
Lbl θ3
ClrDraw
Text(0,0,"2ND-EDIT | ENTER-RESET
{1→ʟC
inString(Str0,",
Repeat not(Ans
  Ans+1→ʟC(1+dim(ʟC
  inString(Str0,",",Ans+1
End
2+length(Str0→ʟC(1+dim(ʟC
dim(ʟC)-1→Q
For(θ,1,Ans
  Text(θ6(|N+1),4(|N+1),sub(Str0,ʟC(θ),ʟC(θ+1)-1-ʟC(θ
End
6(|N+1→X
DelVar ADelVar BDelVar CDelVar DDelVar EDelVar FDelVar GDelVar HDelVar IDelVar ʟBDelVar ʟA
9→dim(ʟA
9→dim(ʟB
{1→ʟD
inString(Str9,",
Repeat not(Ans
  Ans+1→ʟD(1+dim(ʟD
  inString(Str9,",",Ans+1
End
2+length(Str9→ʟD(1+dim(ʟD
Text(57+|N93,75+|N147,"NOTES
Repeat max(K={45
  Text(X,0,"►
  Repeat Ans:getKey→K:End
  Text(X,0,"   "
  X+(6|N+6)((Ans=34 and X<6Q(|N+1))-(Ans=25 and X>6(|N+1→X
  If K=14 or K=15:Then
    ClrDraw
    Text(0,0,"NOTES
    1→X:6(|N+1→A
    While X<length(Str1) and A≤54(|N+1
      inString(Str1,"°",X)-X→B
      min({23+7|N,Ans
      Text(A,0,sub(Str1,X,Ans
      X+Ans+(B≤Ans→X:A+6(|N+1→A
    End
    Repeat getKey:End
    Goto θ3
  End
  If max(K={21,105:Then
    0→J
    X/(6|N+6
    If K=21 and (ʟB(Ans) or not(ʟA(Ans:Then
      Input "VALUE:",J
      X/(6|N+6
      1→ʟB(Ans
    End
    If K=105:Fill(0,ʟB
    X/(6|N+6→K
    If K=1:J→A
    If K=2:J→B
    If K=3:J→C
    If K=4:J→D
    If K=5:J→E
    If K=6:J→F
    If K=7:J→G
    If K=8:J→H
    If K=9:J→I
    If not(ʟB(1:0→A
    If not(ʟB(2:0→B
    If not(ʟB(3:0→C
    If not(ʟB(4:0→D
    If not(ʟB(5:0→E
    If not(ʟB(6:0→F
    If not(ʟB(7:0→G
    If not(ʟB(8:0→H
    If not(ʟB(9:0→I
    For(θ,1,dim(ʟD)-1,2
      sub(Str9,ʟD(θ),ʟD(θ+1)-1-ʟD(θ→Str8
      sub(Str9,ʟD(θ+1),ʟD(θ+2)-1-ʟD(θ+1→Str7
      seq(inString(Str7,sub("ABCDEFGHI",θ,1)),θ,1,9→ʟE
      If 1=sum(not(seq(expr(sub(Str7,θ,1)),θ,1,length(Str7:Then
        expr("solve("+Str8+","+sub(Str7,max(seq(θnot(expr(sub(Str7,θ,1))),θ,1,length(Str7))),1)+",{ᴇ⁻9,ᴇ9
        If ʟE(1) and not(A:Ans→A
        If ʟE(2) and not(B:Ans→B
        If ʟE(3) and not(C:Ans→C
        If ʟE(4) and not(D:Ans→D
        If ʟE(5) and not(E:Ans→E
        If ʟE(6) and not(F:Ans→F
        If ʟE(7) and not(G:Ans→G
        If ʟE(8) and not(H:Ans→H
        If ʟE(9) and not(I:Ans→I
      End
    End
    {A,B,C,D,E,F,G,H,I→A
    For(θ,1,Q
      If not(ʟA(θ:Text(θ6(|N+1),4(|N+1)max(DeltaList(ʟC)),"                                                "
      If ʟA(θ:Text(θ6(|N+1),4(|N+1)max(DeltaList(ʟC)),sub(" = ",1,2not(ʟB(θ))+1),ʟA(θ),"                                "
    End
  End
End
Goto θA
Lbl θ1
Ans→Str0
0→dim(ʟQ
ClrDraw
If |N:TextColor(RED
inString(Str0,",
Text(0,0,sub(Str0,1,Ans-1
Repeat not(Ans
  Ans+1→ʟQ(1+dim(ʟQ
  inString(Str0,",",Ans+1
End
2+length(Str0→ʟQ(1+dim(ʟQ
dim(ʟQ)-1→Q
If |N:TextColor(BLACK
For(θ,1,Ans
  Text(θ6(|N+1),4(|N+1),sub(Str0,ʟQ(θ),ʟQ(θ+1)-1-ʟQ(θ
End
6|N+6→X
ClrList ʟQ
{92,93,94,82,83,84,72,73,74→ʟQ
Repeat max(K=ʟQ) or max(K={24,26,45,105
  Text(X,0,"►
  Repeat Ans:getKey→K:End
  Text(X,0,"   "
  X+(6|N+6)((Ans=34 and X<6Q(|N+1))-(Ans=25 and X>6|N+6→X
End
max(seq(X(K=ʟQ(X)),X,1,dim(ʟQ
If Q≥Ans and max(K=ʟQ:Ans6(|N+1)→X
sum(0 xor fPart(FV₁₀^((cumSum(not(binompdf(14,0→Z
X(2-|N)/12→X
If K=24:Then
  If FV=int(FV:0→FV
  int(FV₁₀^((Z-1))/₁₀^((Z-1→FV
  0→X
Else
  FV+X/₁₀^((Z+not(not(FV→FV
End
If 6=X and not(FV:Goto θθ
If X=Q or K=45:Goto XX
Goto θ0
Lbl θA
int(FV₁₀^(Z))/₁₀^(Z→FV
Lbl θ0
FV
If not(Ans:Goto 00
If Ans=1:Then:"PRE-CALCULUS,1-LINEAR EQUATIONS,2-QUADRATIC FORMULA,3-3D GEOMETRY,4-TRIGONOMETRY,5-CUSTOM NOTE 1,6-CUSTOM NOTE 2,7-CUSTOM NOTE 3,8-QUIT":Goto θ1:End
If Ans=1.1:Then:"LINEAR EQUATIONS,1-EQUATION,2-DISTANCE,3-MIDPOINT,4-QUIT":Goto θ1:End
If Ans=1.11:Then:Input "X₁:",A:Input "Y₁:",B:Input "X₂:",C:Input "Y₂:",D:(B-D)/(A-C→C:⁻AnsA+B→A:ClrHome:Disp "Y=",C,"X+":Pause A:Goto θA:End
If Ans=1.12:Then:Input "X₁:",A:Input "Y₁:",B:Input "X₂:",C:Input "Y₂:",D:Pause √((A-C)²+(B-D)²:Goto θA:End
If Ans=1.13:Then:Input "X₁:",A:Input "Y₁:",B:Input "X₂:",C:Input "Y₂:",D:Pause {.5(A+C),.5(B+D:Goto θA:End
If Ans=1.2:Then:Prompt A,B,C:√(B²-4AC→C:Disp (⁻B-Ans)/(2A:Pause (⁻B+C)/(2A:Goto θA:End
If Ans=1.3:Then:"3D GEOMETRY,1-RECTANGULAR PRISM,2-CUBE,3-SPHERE,4-CYLINDER,5-CONE,6-PYRAMID,7-TROUGH,8-QUIT":Goto θ1:End
If Ans=1.31:Then:Prompt L,W,H:LWH→V:2(HL+LW+HW→A:Disp "VOLUME=",V,"S.A.=":Pause A:Goto θA:End
If Ans=1.32:Then:Prompt S:S³→V:6SS→A:Disp "VOLUME=",V,"S.A.=":Pause A:Goto θA:End
If Ans=1.33:Then:Prompt R:4πR³/3→V:4πRR→A:Disp "VOLUME=",V,"S.A.=":Pause A:Goto θA:End
If Ans=1.34:Then:Prompt R,H:πRRH→V:2πR(H+R→A:Disp "VOLUME=",V,"S.A.=":Pause A:Goto θA:End
If Ans=1.35:Then:Prompt R,H:√(RR+HH→S:πRRH/3→V:πR(R+S→A:Disp "VOLUME=",V,"S.A.=":Pause A:Goto θA:End
If Ans=1.36:Then:Prompt L,H,W:LWH/3→V:LW+L√(WW/4+HH)+W√(LL/4+HH→A:Disp "VOLUME=",V,"S.A.=":Pause A:Goto θA:End
If Ans=1.37:Then:Prompt L,W,H:Disp "VOLUME=":Pause LWH/2:Goto θA:End
If Ans=1.4:Then:"sin²θ+cos²θ=1°1+tan²θ=sec²θ°1+cot²θ=csc²θ°sin2θ=2sinθcosθ°cos2θ=cos²θ-sin²θ°cos²θ=0.5(1+cos2θ)°sin²θ=0.5(1-cos2θ)°tan(A+B)=(tanA+tanB)/(1-tanAtanB)°tan(A-B)=(tanA-tanB)/(1+tanAtanB)°":Goto θ2:End
If Ans=1.5:Then:"CUSTOM NOTE 1,1-VIEW NOTE,2-ADD NOTE,3-QUIT":Goto θ1:End
If Ans=1.51:Then:Equ►String(|u,Str1):Str1+"°":Goto θ2:End
If Ans=1.52:Then:"1":Goto θ4:End
If Ans=1.6:Then:"CUSTOM NOTE 2,1-VIEW NOTE,2-ADD NOTE,3-QUIT":Goto θ1:End
If Ans=1.61:Then:Equ►String(|v,Str1):Str1+"°":Goto θ2:End
If Ans=1.62:Then:"2":Goto θ4:End
If Ans=1.7:Then:"CUSTOM NOTE 3,1-VIEW NOTE,2-ADD NOTE,3-QUIT":Goto θ1:End
If Ans=1.71:Then:Equ►String(|w,Str1):Str1+"°":Goto θ2:End
If Ans=1.72:Then:"3":Goto θ4:End
If Ans=2:Then:"LIMITS,1-DEFINITION,2-PROPERTIES,3-L'HôPITALS,4-CONTINUITY,5-NONEXISTENT,6-INFINITE,7-QUIT":Goto θ1:End
If Ans=2.1:Then:"THE LIMIT OF f OF n APPROACHES c EQUALS L°":Goto θ2:End
If Ans=2.2:Then:"lim[bf(x)]=blim[f(x)]°lim[f(x)+g(x)]=lim[f(x)]+lim[g(x)]°lim[f(x)g(x)]=lim[f(x)]lim[g(x)]°lim[f(x)/g(x)]=lim[f(x)]/lim[g(x)]°lim(x to a+)=a FROM LEFT°lim(x to a-)=a FROM RIGHT°":Goto θ2:End
If Ans=2.3:Then:"0/0,(+-)infinity/(+-)infinity°lim[f(x)/g(x)]=lim[f'(x)/g'(x)]}°":Goto θ2:End
If Ans=2.4:Then:"lim(x to a)[f(a)]=f(a)°n√(X)|n IS ODD=ALL X°n√(X)|n IS EVEN=X≥0°e^(X)=ALL X°ln(X)=X>0°":Goto θ2:End
If Ans=2.5:Then:"DOES NOT EXIST LIMITS°1/X (X TO 0)°|X|/X (X TO 0)°sin(1/X) (X TO 0)°":Goto θ2:End
If Ans=2.6:Then:"INFINITE LIMITS°1/X² (X TO 0)°ln(X) (X TO 0+)=-INFINITY°":Goto θ2:End
If Ans=3:Then:"DIFFERENTIAL,1-RULES (PART 1),2-RULES (PART 2),3-MEAN VALUE THEOREM,4-INTERMEDIATE V.T.,5-RELATED RATES,6-CURVES+ANALYSIS,7-NORMAL LINE,8-QUIT":Goto θ1:End
If Ans=3.1:Then:"x^n : nx^(n-1)°fg : f'g+fg'°f/g: (f'g-fg')/g²°f(g(x)): f'(g(x))g'(x)°sinx: cosx°cosx: -sinx°tanx: sec²x°cotx: -csc²x°secx: secxtanx°cscx: -cscxcotx°":Goto θ2:End
If Ans=3.2:Then:"e^x: e^x°a^x: a^xlna°ln(x): 1/x°sinˉ¹x: 1/√(1-x²)°cosˉ¹x: -1/√(1-x²)°tanˉ¹x: 1/(1+x²)°c: 0°cf(x): cf'(x)°fˉ¹: 1/f'(fˉ¹(x))°":Goto θ2:End
If Ans=3.3:Then:"IF f(x) IS CONTINUOUS+DIFFERENTIABLE ON [a,b],° °f'(c)=(f(b)-f(a))/(b-a)°":Goto θ2:End
If Ans=3.4:Then:"IF f(x) IS CONTINUOUS ON [a,b], f(d)=c, WHERE c IS BETWEEN a AND b°":Goto θ2:End
If Ans=3.5:Then:"RELATED RATES,1-LADDER,2-CYLINDER,3-CONE,4-SPHERE,5-POLE SHADOW,6-QUIT":Goto θ1:End
If Ans=3.51:Then:"X-DISTANCE,Y-DISTANCE,LADDER LENGTH,dX/dT,dY/dT"→Str0:"A²+B²-C²,ABC,AD+BE,ABDE"→Str9:"THIS SOLVES FOR A FALLING LADDER°"→Str1:Goto θ3:End
If Ans=3.52:Then:"R₁,H₁,V₁,H,V,dH/dT,dV/dT"→Str0:"πA²B-C,ABC,πA²D-E,ADE,πA²F-G,AFG"→Str9:"THIS SOLVES FOR A CYLINDER. R₁ IS THE ACTUAL RADIUS°"→Str1:Goto θ3:End
If Ans=3.53:Then:"R₁,H₁,V₁,R,H,V,dR/dT,dH/dT,dV/dT"→Str0:"D/A-E/B,ABDE,1/3πA²B-C,ABC,1/3πD²E-F,DEF,A²πE²H/B²-I,ABEHI,BπD²G/A-I,ABDGI"→Str9:Goto θ3:End
If Ans=3.54:Then:"RADIUS,VOLUME,S.AREA,dR/dT,dV/dT,dSA/dT"→Str0:"4/3πA³-B,AB,4πA²-C,AC,4πA²D-E,ADE,8πAD-F,ADF"→Str9:Goto θ3:End
If Ans=3.55:Then:"LAMP HEIGHT,PERSON HEIGHT,PERSON DIST.,SHADOW TIP DIST.,SHADOW LENGTH,dX/dT,dSTip/dT,dSLength/dT"→Str0:"C+BC/(A-B)-D,ABCD,(A-B)/C-B/E,ABCE,BF/(A-B)-H,ABFH,F+H-G,FGH"→Str9:Goto θ3:End
If Ans=3.6:Then:"f(x) MUST BE CONTINUOUS°CRITICAL POINT:f'=0 or UND°MINIMUM:°f' IS (-,0 or UND,+) or f''>0°MAXIMUM:°f' IS (+,0 or UND,-) or f''<0°INFLECTION:°f'' IS (+,0 or UND,-) or (-,0 or UND,+)°":Goto θ2:End
If Ans=3.7:Then:Disp "NORMAL LINE","PERPENDICULAR TO","SLOPE":Input "f(x):",Str1:Str1→Y₉:Input "POINT:",A:Disp "Y=",⁻1/nDeriv(Y₉,X,A),"(X-",A,")+":Pause Y₉(A:FnOff :Goto θA:End
If Ans=4:Then:"INTEGRAL,1-PROPERTIES,2-COMMON RULES,3-FUNDAMENTAL T.O.C. 1+2,4-RIEMANN SUMS,5-CROSS SECTION,6-REVOLVED SOLIDS,7-ARC LENGTH,8-EULER'S METHOD,9-QUIT":Goto θ1:End
If Ans=4.1:Then:"∫(f+g)=∫f+∫g°∫Cf=C∫f°∫C FROM a TO b=C(b-a)°∫f FROM a TO a=0°⁻∫f FROM a TO b=∫f FROM b TO a°":Goto θ2:End
If Ans=4.2:Then:"REMEMBER +C°∫K=KX°∫X^n=X^(n+1)/(n+1)°∫Xˉ¹=ln(X)°∫1/(aX+b)=1/a|ln(aX+b)|°∫ln(X)=Xln(X)-X°∫cos(X)=sin(X)°∫sin(X)=⁻cos(X)°∫tan(X)=ln(|sec(X)|)°":Goto θ2:End
If Ans=4.3:Then:"FTC THEOREM 1°∫f FROM a TO b=F(b)-F(a)°WHERE F'(x)=f(x)°FTC THEOREM 2°IF f IS CONTINUOUS,°d/dX∫f(t)dt FROM a TO X=f(X)°":Goto θ2:End
If Ans=4.4:Then:"RIEMANN SUMS,1-GIVEN FUNCTION,2-GIVEN TABLE,3-QUIT":Goto θ1:End
If Ans=4.41:Then:Input "f(x):",Str1:Input "Lower Bound:",A:Input "Upper Bound:",B:Input "# of Divisions:",C:Str1→Y₉:(B-A)/C→D:seq(X,X,A,B,D→L₁:DeltaList(cumSum(Ans→L₂:SortD(L₁:DeltaList(cumSum(L₁→L₃:Disp "LEFT RECT.",Dsum(Y₉(Ans:Disp "RIGHT RECT.",Dsum(Y₉(L₂:Pause :Disp "MIDPOINT",Dsum(Y₉(seq(X,X,A+.5D,B,D:Disp "TRAPEZOID",.5Dsum(augment(Y₉(L₂),Y₉(L₃:FnOff :Pause :Goto θA:End
If Ans=4.42:Then:Disp "INPUT EQUISPACED","DATA AS A LIST":Input "{",Str1:expr("{"+Str1→L₁:Input "# of Divisions:",A:Input "INTERVAL WIDTH:",C:(dim(L₁)-1)/A→B:seq(fPart((X-1)/B)=0,X,1,dim(L₁)→L₂:Disp "LEFTRAM",C(sum(L₁L₂)-L₁(dim(L₁:Disp "RIGHTRAM",C(sum(L₁L₂)-L₁(1:Pause :Disp "MIDPOINT",Csum(L₁seq(fPart((X-.5B-1)/B)=0,X,1,dim(L₁:Disp "TRAPEZOID",.5Csum(L₁*(seq(fPart((X-1)/B)=0,X,1,dim(L₁))+seq((X≠1)(X≠dim(L₁))(fPart((X-1)/B)=0),X,1,dim(L₁:Pause :Goto θA:End
If Ans=4.5:Then:"WATCH AXES AND BOUNDS°SQUARE: 1∫f(X)²dX°SEMI-CIRCLE: π/8∫f(X)²dX°EQUI. Δ: √3/4∫f(X)²dX°RECTANGLE: [HEIGHT]∫f(X)²dX°ISOSCELES Δ (LEG IS BASE): 1/2∫f(X)²dX°ISOSCELES Δ (HYPO. IS BASE): 1/4∫f(X)²dX°":Goto θ2:End
If Ans=4.6:Then:"DISK METHOD:°V=π∫R(X)²dX°WASHER METHOD:°V=π∫(R(X)²-r(X)²)dX°IF AXIS OF REVOLUTION>0:°V=π∫((R-a)²-(r-a)²)dX°IF AXIS OF REVOLUTION<0:°V=π∫((R+a)²-(r+a)²)dX°SURFACE OF REVOLUTION:°S=2π∫r(X)√(1+f'(X)²)°":Goto θ2:End
If Ans=4.7:Then:"ARC LENGTH=°∫√(1+[f'(X)]²)dX°":Goto θ2:End
If Ans=4.8:Then:Input "dY/dX EQUATION:",Str1:Str1→Y₉:Input "X₁:",X:Input "Y₁:",Y:Input "ΔX:",A:Input "TARGET X:",B:Repeat X≥B:Y+Y₉A→Y:X+A→X:Disp "X",X,"Y":Pause Y:End:FnOff :Goto θA:End
If Ans=5:Then:"OTHER,1-MODELING,2-PARAMETRIC,3-POLAR,4-SERIES,5-GENERAL TAYLOR,6-MACLAURIN SERIES,7-TAYLOR ERROR,8-QUIT":Goto θ1:End
If Ans=5.1:Then:"MODELING,1-GROWTH AND DECAY,2-G+D SOLVER,3-LOGISTIC,4-LOGISTIC SOLVER,5-COOLING/HEATING,6-HALF-LIFE,7-QUIT":Goto θ1:End
If Ans=5.11:Then:"RATE OF CHANGE OF Y PROPORTIONAL°TO Y:°dY/DT=kY°Y=Ce^(kt)°C IS AT INITIAL°":Goto θ2:End
If Ans=5.12:Then:"Y₁,X₂,Y₂,C,k,X,Y"→Str0:"A-D,AD,Ae^(BE)-C,ABCE,Ae^(EF)-G,AEFG"→Str9:"Y₁ SHOULD BE WHEN X₁ IS 0°"→Str1:Goto θ3:End
If Ans=5.13:Then:"dP/dT=kP(1-P/L)°P(T)=L/(1+Be^(⁻kT)°":Goto θ2:End
If Ans=5.14:Then:"LIMIT,B,K,INITIAL POP.,TIME₁,POP.₁,TIME,POP.,dP/dT"→Str0:"A/(1+B)-D,ABD,A/(1+Be^(⁻CE))-F,ABCEF,A/(1+Be^(⁻CG))-H,ABCGH,CH(1-H/A)-I,ACHI"→Str9:"INITIAL POPULATION IS WHEN T=0°"→Str1:Goto θ3:End
If Ans=5.15:Then:"H(T)=Ce^(kT)+[SURROUNDING TEMPERATURE]°":Goto θ2:End
If Ans=5.16:Then:"1/2=1e^(KT)°K=ln(1/2)/[HALF LIFE]°":Goto θ2:End
If Ans=5.2:Then:"PARAMETRIC,1-VELOCITY VECTOR,2-SPEED,3-DISTANCE,4-SLOPE,5-QUIT":Goto θ1:End
If Ans=5.21:Then:"<x',y'>°":Goto θ2:End
If Ans=5.22:Then:"|\v|=√(x')²+(y')²)°":Goto θ2:End
If Ans=5.23:Then:"D=∫√((x')²+(y')²)°":Goto θ2:End
If Ans=5.24:Then:"y'/x'°":Goto θ2:End
If Ans=5.3:Then:"POLAR,1-BASIC NOTES,2-TANGENTS,3-SLOPE IN POLAR FORM,4-AREA,5-ARC LENGTH,7-QUIT":Goto θ1:End
If Ans=5.31:Then:"X=Rcos(θ)°Y=Rsin(θ)°tan(θ)=Y/X°X²+Y²=R²°":Goto θ2:End
If Ans=5.32:Then:"TANGENTS°HORIZONTAL: dY/dθ=0°VERTICAL: dX/dθ=0°":Goto θ2:End
If Ans=5.33:Then:"dY/dX=(dY/dθ)/(dX/dθ)=°(f(θ)cos(θ)+f'(θ)sin(θ))/°(f'(θ)cos(θ)-f(θ)sin(θ))°":Goto θ2:End
If Ans=5.34:Then:"A=1/2∫f(θ)²dθ or °A=1/2∫(R²-r²)dθ°":Goto θ2:End
If Ans=5.35:Then:"S=∫(√(r²-(dr/dθ)²))dθ°":Goto θ2:End
If Ans=5.4:Then:"SERIES,1-PROPERTIES,2-TESTS,3-CONVERGENCE RADIUS,4-CONVERGENCE INTERVAL,5-QUIT":Goto θ1:End
If Ans=5.41:Then:"SERIES=SUM OF SEQUENCE°Σa=lims°ΣCa=CΣa°Σa+b=Σa+Σb°":Goto θ2:End
If Ans=5.42:Then:"TESTS,1-nTH TERM,2-GEOMETRIC,3-TELESCOPING,4-p-SERIES,5-ALTERNATING,6-INTEGRAL,7-ROOT,8-RATIO,9-QUIT":Goto θ1:End
If Ans=5.421:Then:"CONVERGENCE° °DIVERGENCE°lim≠0°":Goto θ2:End
If Ans=5.422:Then:"CONVERGENCE°|r|\<1°DIVERGENCE°|r|≥1°COMMENT°SUM=a/(1-r)°":Goto θ2:End
If Ans=5.423:Then:"CONVERGENCE°lim=L°DIVERGENCE° °COMMENT°SUM=b₁-L°":Goto θ2:End
If Ans=5.424:Then:"CONVERGENCE°p>1°DIVERGENCE°p≤1°":Goto θ2:End
If Ans=5.425:Then:"CONVERGENCE°DECREASING AND lim=0°DIVERGENCE°":Goto θ2:End
If Ans=5.426:Then:"CONVERGENCE°∫f DIVERGES°DIVERGENCE°∫f CONVERGES°":Goto θ2:End
If Ans=5.427:Then:"CONVERGENCE°limˣ√a<1°DIVERGENCE°limˣ√a>1°COMMENT°INC IF limˣ√a=1°":Goto θ2:End
If Ans=5.428:Then:"CONVERGENCE°lim(a(n+1)/an)<1°DIVERGENCE°lim(a(n+1)/an)>1°COMMENT°INC IF lim(a(n+1)/an)=1°":Goto θ2:End
If Ans=5.43:Then:"USE RATIO TEST°DETERMINE LIMIT WITHOUT X°RoC=1/K°":Goto θ2:End
If Ans=5.44:Then:"FIND CENTER OF SERIES°USE RoC TO FIND INTERVAL°CHECK ENDPOINTS FOR DIVERGENCE°":Goto θ2:End
If Ans=5.5:Then:"f(X)=f(a)+f'(a)(X-a)°+f''(a)/2!(X-a)²°+f^n(a)/n!(X-a)^n°":Goto θ2:End
If Ans=5.6:Then:"e^(X):°1+X+X²/2+X³/3!…°cos(X):°1-X²/2+X^4/4!…°sin(X)=X-X³/3!+X^5/5!…°1/(1-X):°1+X+X²+X³…°ln(X+1):°X-X²/2+X³/3+X^4/4…°":Goto θ2:End
If Ans=5.7:Then:"ERROR=MAXIMUM/(n+1)!(X-1)^(n+1)°":Goto θ2:End
Lbl θθ
ClrDraw
6(|N+1
Text(0,0,"CALCULUS PROGRAM HELP
Text(2Ans,0,"PRESS ↑ OR ↓ TO MOVE CURSOR
Text(3Ans,0,"PRESS ► OR ENTER TO SELECT
Text(4Ans,0,"PRESS ◄ TO GO BACK
Text(5Ans,0,"PRESS CLEAR TO QUIT
Text(6Ans,0,"PRESS ANY KEY TO EXIT HELP
Text(8Ans,0,"COMPATIBLE WITH TI-83+ &
Text(9Ans,0,"    TI-84+/SE/CSE/CE
Repeat getKey:End
Goto 00
Lbl XX
ClrHome
RecallGDB GDB1
|N
Output(3+Ans,1+Ans5,"CALCULUS PROGRAM
Output(4+Ans,7+Ans5,"v1.3
Output(5+Ans,4+Ans5,"CREATED BY
Output(6+Ans,2+Ans5,"ELECTROMAGNET8
Return