I made a basic planet generator.


Code:
startTmr->T
ClrHome
Output(1,1,"INITIALIZING
6378->R
{Blue,LtBlue,Green,Orange,Brown,Gray->|LC
{R,1.00055R,1.0006R,1.001R,1.0012R,1.00135R->|LE
840->dim(|LA:840->dim(|LB
R+.002Rrand(840->|LR
DelVar P
For(B,180,0,~9
   For(A,1,360,9
      P+1->P
      B->|LB(P:A->|LA(P
End:End
Output(1,1,"SMOOTHING   
DelVar P
For(S,1,3
   For(B,1,19
      For(A,1,40
         40B+A
         (8|LR(Ans)+|LR(Ans+1)+|LR(Ans-1)+|LR(Ans+40)+|LR(Ans-40))/12->|LR(Ans
         P+1->P
         Output(1,12,round(P/22.8,2)
   End:End
End
min(1.00138R,max(R,~0.0003R+|LR->|LR
Output(3,1,"CONVERTING POINTS
Output(4,2,"FROM POLAR TO CARTESIAN
|LRsin(|LB)cos(|LA->|LX
|LRsin(|LB)sin(|LA->|LY
|LRcos(|LB->|LZ
Output(5,2,"FROM 3D TO 2D
cos(30^^o)(|LX+|LY->|LXP
sin(50^^o)(|LZ+(|LX-|LY->|LYP
Output(7,1,"DRAWING
min(|LYP->Ymin:1.6Ans->Xmin:max(|LYP->Ymax:1.6Ans->Xmax
ClrDraw
For(B,0,20
   For(A,1,40
      40B+A
      If B<20:Then
         Line(|LXP(Ans),|LYP(Ans),|LXP(Ans+40),|LYP(Ans+40),|LC(sum(|LE<=min(|LR(Ans),|LR(Ans+40))))
         Line(|LXP(Ans),|LYP(Ans),|LXP(Ans+39),|LYP(Ans+39),|LC(sum(|LE<=min(|LR(Ans),|LR(Ans+39))))
      End
      If Ans<840
      Line(|LXP(Ans),|LYP(Ans),|LXP(Ans+1),|LYP(Ans+1),|LC(sum(|LE<=min(|LR(Ans),|LR(Ans+1))))
End:End
TextColor(Black
Text(0,0,"TIME: ",checkTmr(T
  
Register to Join the Conversation
Have your own thoughts to add to this or any other topic? Want to ask a question, offer a suggestion, share your own programs and projects, upload a file to the file archives, get help with calculator and computer programming, or simply chat with like-minded coders and tech and calculator enthusiasts via the site-wide AJAX SAX widget? Registration for a free Cemetech account only takes a minute.

» Go to Registration page
Page 1 of 1
» All times are UTC - 5 Hours
 
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum

 

Advertisement