Login [Register]
Don't have an account? Register now to chat, post, use our tools, and much more.

Would you find this useful?
Yes!
 77%  [ 7 ]
No.
 22%  [ 2 ]
Total Votes : 9

I trying to make a program that'll make hard coding sprites easier.

With this program you'll be able to: (Done, Finished but untested, in progress, not started, not possible) ['as of' version number]
-Make more complex sprites easily
-Make line sprites [v.9]
-Make fine or thick sprites
-Easily get a friendly window
-Save your project and finish it later
-Load a background sprite
-Easily change colors of sprite.
-Auto-save
-Undo
-Delete [v.9]
-Adjust speed of cursor
-Test dot sprite:
--Rotate sprite

--Reflections
--Translations
--Stretching

Here's what I have so far.


If you have any questions or ideas for this please post.
This would be a rather nice tool, and I would gladly donate code samples from my earlier attempts making something similar.
You may want to have a look at a previous topic of mine that never quite got completed, but the editing sprites part got completed.
The idea was to be able to create or edit xLIBc(e) spritesheets on-calc.
Here is a link.
Hey I got a rough program done! I'm going out-of-state so I wont be able to work on this until either Thursday or Friday. But until then, I need some 'gamma testers', this is such an early program I can't call it a 'beta release' Razz. I'm putting it out there since I'll be gone a while and I still want feedback.

Gamma testers: Tell me what you like, dislike, and what you'd like to see implemented. If you run into a bug please note the exact steps to get this bug.

I know a few features aren't functioning right now and this is about as bugy as Windows 10, but I'll fix those when I get back.

Here it is AAIONIA V.1 Gamma release 1 (Note: This code may change without notice until 6/18/17 at 9:45 CDT)


Code:
ClrHome
Disp "     AAIONIA","v.1 Gamma release 1","","Loading..."
FnOff
ClrDraw
DetectAsymOff
BackgroundOff

15→C
0→K
.5→X
.5→Y

SetUpEditor ⌊AACDX,⌊AACDY,⌊AAOPS,⌊AAX1,⌊AAY1,⌊AAX2,⌊AAY2
"pen X and Y lists"
1→dim(⌊AACDX
1→dim(⌊AACDY
"1 is pen color(not functioning), 2 is secondary sprite color (not functioning), 3 is pen thickness, 4 is second sprite thickness, "
10→dim(⌊AAOPS
1→dim(⌊AAX1
1→dim(⌊AAY1
1→dim(⌊AAX2
1→dim(⌊AAY2

If ⌊AAOPS(2)=0
15→⌊AAOPS(2)

0→⌊AAX2(1)
0→⌊AAY2(1)
0→⌊AACDX(1)
0→⌊AACDY(1)

Lbl 00
ClrHome
"note to self: do Window"
Menu("AAIONIA setup 1","DRAW!",D1,"Color",C1,"Thickness",T1,"Add sprite",A1,"Adjust window",W1


Lbl D1
Menu("DRAW","New",01,"Load and continue",L1,"BACK",00

Lbl L1
Input "Enter X coordinate list:",⌊AAX1
Input "Enter Y coordinate list:",⌊AAY1
Pause "Press ENTER"
Goto 01

Lbl C1
Menu("COLOR <NOT FUNCTIONING>","Pen color",C2,"Secondary sprite",C3,"BACK",00

Lbl C2
Input "Enter color for sprite:",A
A→⌊AAOPS(1)
Pause "Success! Press ENTER"
Goto 00

Lbl C3
Input "Enter secondary color:",A
A→⌊AAOPS(1)
Pause "Success! Press ENTER"
Goto 00

Lbl T1
Menu("THICKNESS","Thick ()",T2,"Fine  ()",T3,"BACK",00

Lbl T2
1→⌊AAOPS(3)
Pause "Success! Press ENTER"
Goto 00

Lbl T3
0→⌊AAOPS(3)
Pause "Success! Press ENTER"
Goto 00

Lbl A1
Disp "<NOT FUNCTIONING>"
Input "Enter X coordinate list:",⌊AAX2
Input "Enter Y coordinate list:",⌊AAY2
Disp "Enter 1 for thick sprite","Enter 0 for thin sprite"
Input "Thickness:",A
A→⌊AAOPS(4)
Pause "Success! Press ENTER"
Goto 00

Lbl W1
Disp "Not yet implemented","Press enter"
Pause
Goto 00

"--------------------------------
Lbl 01
Text(150,1,"Save   Quit       DecSpeed     IncSpeed   Undo
DispGraph
While K≠45

getKey→K
"I know this is super inefficient, but I cant get any other way to work"
If K=24
⌊AACDX(1)-X→⌊AACDX(1)
If K=26
⌊AACDX(1)+X→⌊AACDX(1)
If K=25
⌊AACDY(1)+X→⌊AACDY(1)
If K=34
⌊AACDY(1)-X→⌊AACDY(1)
If ⌊AACDX(1)>Xmax
⌊AACDX(1)-X→⌊AACDX(1)
If ⌊AACDX(1)<Xmin
⌊AACDX(1)+X→⌊AACDX(1)
If ⌊AACDY(1)>Ymax
⌊AACDY(1)-X→⌊AACDY(1)
If ⌊AACDY(1)<Ymin
⌊AACDY(1)+X→⌊AACDY(1)

"I dont want to deal with the secondary sprite right now"
While 0
"secondary sprite"
If ⌊AAX2(1)≠0 and ⌊AAY2(1)≠0
Then
:If ⌊AAOPS(4)=1
:Then
:Plot1(Scatter,⌊AAX2,⌊AAY2,
:Else
:Plot1(Scatter,⌊AAX2,⌊AAY2,
End
End

"prim sprite"
If ⌊AAOPS(3)=1
Then
Plot2(Scatter,⌊AAX1,⌊AAY1,
Else
Plot2(Scatter,⌊AAX1,⌊AAY1,
End

"Pen"
If ⌊AAOPS(3)=1
Then
Plot3(Scatter,⌊AACDX,⌊AACDY,
Else
Plot3(Scatter,⌊AACDX,⌊AACDY,
End

"5 buttons 11 save, 12 quit, 13 decSpeed, 14 inc speed, 15 undo"
If K=11
Goto S1
If K=12
Goto E1
If K=13
Then
X-.05→X
Y-.05→X
End
If K=14
Then
X+.05→X
Y+.05→Y
End
If K=15
Then
List(cumSum(⌊AAX1)-⌊AAX1→⌊AAX1
List(cumSum(⌊AAY1)-⌊AAY1→⌊AAY1
End

"must be here to disp correctly"
If max(K={15,21,24,25,26,34
Then
DispGraph
Text(150,1,"Save   Quit       DecSpeed     IncSpeed   Undo
End

"Saving feature"
If K=21 or K=105
Then
augment(⌊AAX1,⌊AACDX→⌊AAX1
augment(⌊AAY1,⌊AACDY→⌊AAY1
If T=10
Then
0→T
⌊AAX1→L₃
⌊AAY1→L₄
Text(10,1,"Autosaved to L₃ & L₄
1+T→T
End
End

End
Goto 99

Lbl E1
Menu("Quit without saving?","Save",S1,"Quit without saving",99,"BACK",01

Lbl S1
Menu("Save?","Save and continue",S2,"Save and quit",S3,"BACK",01

Lbl S2
⌊AAX1→L₁
⌊AAY1→L₂
Disp "Your X coordinates have","been stored in L₁","Your Y coordinates have","been stored in L₂","Press Enter"
Pause
Goto 01

Lbl S3
⌊AAX1→L₁
⌊AAY1→L₂
Disp "Your X coordinates have","been stored in L₁","Your Y coordinates have","been stored in L₂","Please store these","coordinates in a new list","as L₁ & L₂ will be","overwritten."

Lbl 99
DelVar ⌊AACDX
DelVar ⌊AACDY
DelVar ⌊AAX1
DelVar ⌊AAY1
DelVar ⌊AAX2
DelVar ⌊AAY2
DelVar X
DelVar Y
AxesOn
PlotsOff
FnOn
"End!
Sorry for the double post, but this needs to be separated from the previous post.

I haven't gotten much feed back on this so I've made a poll to see how many people are actually interested in this.

I've finished Gamma release 2 which fixes many bugs with gamma 1 and adds in many new features, including saving your current zoom to use later, a better auto save feature, and an actual ReadMe!

Gamma testers: Tell me what you like, dislike, and what you'd like to see implemented. If you run into a bug please note the exact steps to get this bug.

[Refreshed at 1:56 PM CDT]
Download here

I'll try to get a screenshot in when I get back from vacation.
Some errors:
When adjusting window to "suggested for thick" text runs off screen
Syntax error when window is adjusted to "suggested for thin"
Undo gives dimension error

An additional note: Maybe I don't understand how its supposed to work, but the arrows keys don't seem to do anything in the draw screen? How am I supposed to draw the sprites...
dankcalculatorbro wrote:
Some errors:
When adjusting window to "suggested for thick" text runs off screen
Syntax error when window is adjusted to "suggested for thin"
found and fixed!
dankcalculatorbro wrote:
Undo gives dimension error
this does happen if you have nothing on the screen and you press it. I'm working on preventing that. Does it still happen if you place down a few points first?
dankcalculatorbro wrote:

An additional note: Maybe I don't understand how its supposed to work, but the arrows keys don't seem to do anything in the draw screen? How am I supposed to draw the sprites...
I guess I forgot to include that in the ReadMe Rolling Eyes. when you move the arrow keys a 'cursor' appears that marks where you are about to place a point. Press [Enter] or [2nd] to place a point. Very Happy

Thanks dankcalculatorbro! I really appreciate this. Smile
So now that I'm back, I'm attempting to get the plot colors working.

I know I can do this

Code:
Plot1(<type>,<list>,<list>,<type>,<color>

The problem is, the color isn't being saved. So if the plot color in the calculator settings is RED and you did Plot1(<type>,<list>,<list>,<type>,BLUE it would correctly plot the coordinates the color BLUE. But later if you did Plot1(<type>,<list>,<list>,<type> it would revert back to plotting the coordinates RED.

My original solution was "use a variable!" but that throws an ERROR: INVALID.

I cant just do

Code:
Input "color",A
If A=BLUE
Then
Plot2(Scatter,L₁,L₂,,BLUE
Plot3(Scatter,L₁,L₂,,BLUE
End
If A=RED
Then
Plot2(Scatter,L₁,L₂,,RED
Plot3(Scatter,L₁,L₂,,RED
End
//etc...

That's just way too slow.

My second problem is my cursor movement code is atrocious, there has got to be a better way than what I have

Code:
getKey→K
If K=24
⌊AACDX(1)-X→⌊AACDX(1)
If K=26
⌊AACDX(1)+X→⌊AACDX(1)
If K=25
⌊AACDY(1)+X→⌊AACDY(1)
If K=34
⌊AACDY(1)-X→⌊AACDY(1)
If ⌊AACDX(1)>Xmax
⌊AACDX(1)-X→⌊AACDX(1)
If ⌊AACDX(1)<Xmin
⌊AACDX(1)+X→⌊AACDX(1)
If ⌊AACDY(1)>Ymax
⌊AACDY(1)-X→⌊AACDY(1)
If ⌊AACDY(1)<Ymin
⌊AACDY(1)+X→⌊AACDY(1)

I've tried

Code:
max(Xmax,min(Xmin,X+sum(ΔList(Ans={24,26->⌊AACDX(1)
max(Ymax,min(Ymin,X+sum(ΔList(K={25,34->⌊AACDY(1)

But this keeps the cursor outside the window boundaries. if I flip the locations (Xmax with Xmin and Ymax with Ymin etc.) then it keeps the cursor within a 4x4 square around the origin.


So my questions are: Is there any way to save a plot color in-program? or will I have to give instructions on how to manually change the plot color? And how do I optimize my movement code?

EDIT:
So I tried

Code:
Input "color",A
expr("Plot1(Scatter,L₁,L₂,▫,"+sub("REDBLUE",A-RED,1

Would this be the correct syntax for this?
Plotn seems to insist on color tokens while refusing all other forms of computation.

Second problem fix:

Code:
min(Xmax,max(Xmin,⌊AACDX(1)+Xsum(ΔList(Ans={24,26→⌊AACDX(1)
min(Ymax,max(Ymin,⌊AACDY(1)+Xsum(ΔList(K={34,25→⌊AACDY(1)

You swapped min( and max( as well as 25 and 34, and your step-by-X logic was lost in translation.

If you replace the innermost sum( with min( or max(, it should be about 2 seconds faster per line over 10,000 iterations.
Weregoose wrote:
Plotn seems to insist on color tokens while refusing all other forms of computation.
That's unfortunate. Sad I guess I'll just have to put instructions on how to change it manually. Thanks for going through all that trouble to help me though. Smile

Weregoose wrote:

Second problem fix:

Code:
min(Xmax,max(Xmin,⌊AACDX(1)+Xsum(ΔList(Ans={24,26→⌊AACDX(1)
min(Ymax,max(Ymin,⌊AACDY(1)+Xsum(ΔList(K={34,25→⌊AACDY(1)

You swapped min( and max( as well as 25 and 34, and your step-by-X logic was lost in translation.

Thanks so much for this! you just made my program quite a bit faster. Very Happy

Weregoose wrote:

If you replace the innermost sum( with min( or max(, it should be about 2 seconds faster per line over 10,000 iterations.


Do you mean something like this?

Code:
min(Xmax,max(Xmin,⌊AACDX(1)+Xmax(ΔList(Ans={24,26→⌊AACDX(1)
min(Ymax,max(Ymin,⌊AACDY(1)+Xmax(ΔList(K={34,25→⌊AACDY(1)

or

Code:
min(Xmax,max(Xmin,⌊AACDX(1)+Xmin(ΔList(Ans={24,26→⌊AACDX(1)
min(Ymax,max(Ymin,⌊AACDY(1)+Xmin(ΔList(K={34,25→⌊AACDY(1)


Anyways, thanks for all your help Weregoose!
Lots of double posts... Razz

I'm trying to get this to display my sprite as a thick sprite, now it works but it still keeps breaking my main code
Code:
"secondary sprite
"secondary sprite
{1,2,3,4}→⌊AAX2
{4,3,2,1}→⌊AAY2
1→⌊AAOPS(4)
If ⌊AAX2(1)≠0 and ⌊AAY2(1)≠0
Then
If ⌊AAOPS(4)=1
Then
Plot1(Scatter,⌊AAX2,⌊AAY2,
Else
Plot1(Scatter,⌊AAX2,⌊AAY2,
End
End
DispGraph
Pause 


Why does this not work? I assume it has to do with my nested If statements. Also, this keeps breaking my program. Right now I have it blocked in a While 0 loop, but if I take it out of the loop then my code just refuses to work at all. I've done some bug testing (putting Disp "enter number here" in strategic locations) and the program is still running through everything, it's just ignoring my commands for some reason.

Here's my entire code (with the secondary sprite code in a While 0 loop which is on line 185 and marked with ######)

Code:
ClrHome
Disp "     AAIONIA","v.1 Gamma release 2","","Loading...
FnOff
ClrDraw
DetectAsymOff
BackgroundOff

15→C
0→K
2→T
.5→X
.5→Y

"End!→Str1

SetUpEditor ⌊AACDX,⌊AACDY,⌊AAOPS,⌊AAX1,⌊AAY1,⌊AAX2,⌊AAY2,⌊AAJNK
"pen X and Y lists
1→dim(⌊AACDX
1→dim(⌊AACDY
"1 is pen color(not functioning), 2 is secondary sprite color (not functioning), 3 is pen thickness, 4 is second sprite thickness, 5 is AATEST compression/ stretch
10→dim(⌊AAOPS
1→dim(⌊AAX1
1→dim(⌊AAY1
1→dim(⌊AAX2
1→dim(⌊AAY2
1→dim(⌊AAJNK

If ⌊AAOPS(2)=0
15→⌊AAOPS(2)

0→⌊AAX2(1)
0→⌊AAY2(1)
0→⌊AACDX(1)
0→⌊AACDY(1)

Lbl 00
ClrHome
"note to self: do Window
Menu("AAIONIA setup 1","DRAW!",D1,"Color",C1,"Thickness",T1,"Add sprite",A1,"Adjust window",W1,"Test it!",V1,"QUIT",99


Lbl D1
Menu("DRAW","New",01,"Load and continue",L1,"BACK",00

Lbl L1
Input "Enter X coordinate list:",⌊AAX1
Input "Enter Y coordinate list:",⌊AAY1
Pause "Press ENTER"
Goto 01

Lbl C1
Disp "Not functioning","press enter"
Pause
Goto 00
Menu("COLOR","Pen color",C2,"Secondary sprite",C3,"BACK",00

Lbl C2
Disp "press [2nd]+[stat plot],","press 2 and scroll down","to 'Color:'","change color with ","left/ right arrow keys"
Pause
Disp "then do the same but with Plot3
Pause "Press ENTER"
Goto 99

Lbl C3
Disp "press [2nd]+[stat plot],","press 1 and scroll down","to 'Color:'","change color with ","left/ right arrow keys"
Pause "Press Enter"
Goto 99

Lbl T1
Menu("THICKNESS","Thick ()",T2,"Fine  ()",T3,"BACK",00

Lbl T2
1→⌊AAOPS(3)
Pause "Success! Press ENTER"
Goto 00

Lbl T3
0→⌊AAOPS(3)
Pause "Success! Press ENTER"
Goto 00

Lbl A1
Disp "Enter lists to load:"
Input "Enter X coordinate list:",⌊AAX2
Input "Enter Y coordinate list:",⌊AAY2
Disp "Enter 1 for sprite","Enter 0 for sprite"
Input "Thickness:",A
A→⌊AAOPS(4)
Pause "Success! Press ENTER"
Goto 00

Lbl W1
Menu("Window size","Suggested for thick",W2,"Suggested for thin",W3,"Custom",W4,"Save Current Zoom",W5,"Load Zoom",W6,"BACK",00

Lbl W2
ZStandard
ZSquare
.5→X
.5→Y
Text(10,1,"Sucess!"
Text(25,1,"Currently at standard size,"
Text(40,1,"and square."
Text(55,1,"Press ENTER."
Pause
Goto 00

Lbl W3
ZStandard
ZSquare
Zoom Out
1→X
1→Y
Text(10,1,"Sucess!"
Text(25,1,"Currently at standard size,"
Text(40,1,"square, and zoomed out."
Text(55,1,"Press ENTER."
Pause
Goto 00

Lbl W4
Menu("Custom","Xmin",Z1,"Xmax",Z2","Ymin",Z3,"Ymax",Z4,"BACK",00

Lbl Z1
Disp "Current Xmin:",Xmin
Input "Enter Xmin",Xmin
Goto W4

Lbl Z2
Disp "Current Xmax:",Xmax
Input "Enter Xmax",Xmax
Goto W4

Lbl Z3
Disp "Current Ymin:",Ymin
Input "Enter Ymin",Ymin
Goto W4

Lbl Z4
Disp "Current Ymax:",Ymax
Input "Enter Ymax",Ymax
Goto W4

Lbl W5
Xmin→L₅(1)
Xmax→L₅(2)
Ymin→L₅(3)
Ymax→L₅(4)
Xscl→L₅(5)
Yscl→L₅(6)
X→L₅(7)
Y→L₅(8)
Disp "Sucess!","Zoom has been saved in L₅","Please store L₅ in a new","list to prevent","overwriting","Press enter"
Pause
Menu("Store to new list now?","Yes",99,"No",00

Lbl W6
Input "Load which list? ",L₅
L₅(1)→Xmin
L₅(2)→Xmax
L₅(3)→Ymin
L₅(4)→Ymax
L₅(5)→Xscl
L₅(6)→Yscl
L₅(7)→X
L₅(8)→Y
Pause "Sucess! Press enter"
Goto 00

Lbl V1
prgmAATEST
Goto 00

"--------------------------------
Lbl 01
DispGraph
Text(150,1,"Save   Quit       DecSpeed     IncSpeed   Undo
Text(135,1,"Speed: ",X
While K≠45

getKey→K
min(Xmax,max(Xmin,⌊AACDX(1)+Xsum(List(Ans={24,26→⌊AACDX(1)
min(Ymax,max(Ymin,⌊AACDY(1)+Xsum(List(K={34,25→⌊AACDY(1)

While 0
"secondary sprite ################################################
If ⌊AAX2(1)≠0 and ⌊AAY2(1)≠0
Then
If ⌊AAOPS(4)=1
Then
Plot1(Scatter,⌊AAX2,⌊AAY2,
Else
Plot1(Scatter,⌊AAX2,⌊AAY2,
End
End

"prim sprite
If ⌊AAOPS(3)=1
Then
Plot2(Scatter,⌊AAX1,⌊AAY1,
Else
Plot2(Scatter,⌊AAX1,⌊AAY1,
End


"Pen
If ⌊AAOPS(3)=1
Then
Plot3(Scatter,⌊AACDX,⌊AACDY,
Else
Plot3(Scatter,⌊AACDX,⌊AACDY,
End

"5 buttons 11 save, 12 quit, 13 decSpeed, 14 inc speed, 15 undo
If K=11
Goto S1
If K=12
Goto E1
If K=13
Then
.05+X→X
.05+Y→Y
Text(135,1,"Speed: ",X
End
If K=14
Then
X+.05→X
Y+.05→Y
Text(135,1,"Speed: ",X
End
If K=15
Then
If dim(⌊AAX1)>1
Then
List(cumSum(⌊AAX1)-⌊AAX1→⌊AAX1
List(cumSum(⌊AAY1)-⌊AAY1→⌊AAY1
Else
2→T
End
End

"must be here to disp correctly
If max(K={13,15,21,24,25,26,34,105
Then
DispGraph
Text(150,1,"Save   Quit       DecSpeed     IncSpeed   Undo
Text(135,1,"Speed: ",X
End

"Saving feature
If K=21 or K=105
Then
augment(⌊AAX1,⌊AACDX→⌊AAX1
augment(⌊AAY1,⌊AACDY→⌊AAY1
1+T→T
If T=10
Then
0→T
⌊AAX1→L₃
⌊AAY1→L₄
Text(10,1,"Autosaved to L₃ & L₄
1+T→T
End
If T=1
Then
List(cumSum(⌊AAX1))→⌊AAX1
List(cumSum(⌊AAY1))→⌊AAY1
End
End

End
Goto 99

Lbl E1
Menu("Quit without saving?","Save",S1,"Quit without saving",99,"BACK",01

Lbl S1
Menu("Save?","Save and continue",S2,"Save and quit",S3,"BACK",01

Lbl S2
⌊AAX1→L₁
⌊AAY1→L₂
dim(⌊AAX1→L
Disp "Your X coordinates have","been stored in L₁","Your Y coordinates have","been stored in L₂","Length is in var L","Press Enter"
Pause
Goto 01

Lbl S3
⌊AAX1→L₁
⌊AAY1→L₂
dim(⌊AAX1→L
Disp "Your X coordinates have","been stored in L₁","Your Y coordinates have","been stored in L₂","Length is in var L","Please store these","coordinates in a new list","as L₁ & L₂ will be","overwritten."

Lbl 99
DelVar ⌊AACDX
DelVar ⌊AACDY
DelVar ⌊AAX1
DelVar ⌊AAY1
DelVar ⌊AAX2
DelVar ⌊AAY2
DelVar X
DelVar Y
AxesOn
PlotsOff
FnOn
"End!

I fixed it! now just a few more little things an I'll upload it to the Archives! Very Happy
Why does this program have the name it has?
All right, it's been a little bit. I've added two things that I find are essential and frankly I should have included in my first release. Rolling Eyes

1. A delete function along with undo. I don't know why I didn't think of this before! Razz
2. Ability to make 'line sprites' (that's what I call them). So you can place a line starting point then a line ending point. AAIONIA will connect the two points and make a sprite! This is for sprites that don't need to be so complex.

This will change it to v.9
A little problem. Actually it's more of an optimization question.

For my delete function to work, I need to detect where different numbers are (in the same position(X)) with both ʟAACDX (which stores the cursors current X coordinates) and ʟAACDY (which stores the cursors current Y coordinates)

I need to find the number from ʟAACDX(1) in ʟAAX1(?) and the number from ʟAACDY(1) in ʟAAY1(?).
This is my current code to find where the numbers are, I have no idea if it work properly or not.

Code:
max(seq(X(⌊AACDX(1)=⌊AAX1(X) and ⌊AACDY(1)=⌊AAY1(X)),X,1,dim(⌊AAY1


My next step is deleting the number in position X for both lists ⌊AAX1 and ⌊AAY1. I've tried to make some code to do this myself, but it gives me an invalid dimension error on line 6.

Am I even doing this correctly? Razz

Code:
If K=23
Then
1→X
1→Y
max(seq(X(⌊AACDX(1)=⌊AAX1(X) and ⌊AACDY(1)=⌊AAY1(X)),X,1,dim(⌊AAY1
seq(⌊AAX1(Y),Y,X+1,dim(⌊AAX1)→L₅
seq(⌊AAY1(Y),Y,X+1,dim(⌊AAY1)→L₆
For(A,dim(⌊AAX1),dim(⌊AAX1)-X,-1
List(cumSum(⌊AAX1)-⌊AAX1→⌊AAX1
List(cumSum(⌊AAY1)-⌊AAY1→⌊AAY1
End
augment(⌊AAX1,L₅)→⌊AAX1
augment(⌊AAY1,L₆)→⌊AAY1
End


My theory on how this should work
(I'll only use ⌊AAX1 in this theory) I'm thinking I will have to break off the end of ⌊AAX1 and save that to a sub list, then I need to just delete the last element of ⌊AAX1, then augment the sublist and ⌊AAX1 back together.
I feel like there an easier way to do this though... Any ideas?

EDIT: Yep, there's an easier way Razz

Thank you so much PT_! The 'Delete' is now green!

Code:
If K=23
Then
1+sum(not(cumSum(⌊AACDX(1)=⌊AAX1 and ⌊AACDY(1)=⌊AAY1→A
seq(⌊AAX1(X-(X≤A)),X,2,dim(⌊AAX1→AAX1
seq(⌊AAY1(X-(X≤A)),X,2,dim(⌊AAY1→AAY1
End
  
Register to Join the Conversation
Have your own thoughts to add to this or any other topic? Want to ask a question, offer a suggestion, share your own programs and projects, upload a file to the file archives, get help with calculator and computer programming, or simply chat with like-minded coders and tech and calculator enthusiasts via the site-wide AJAX SAX widget? Registration for a free Cemetech account only takes a minute.

» Go to Registration page
Page 1 of 1
» All times are GMT - 5 Hours
 
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum

 

Advertisement