My TI-BASIC programs
» >
» Goto page Previous  1, 2, 3, 4, 5, 6  Next
» View previous topic :: View next topic  
I will try that. Plus, I have little idea what I could even do to start. But where would the fun in programming be if you knew everything? :wink:





*My programs are NEVER finished
TI_Coder wrote:
I will try that. Plus, I have little idea what I could even do to start. But where would the fun in programming be if you knew everything? Wink
Exactly, the whole point is learning something new and challenging yourself.

Edit: Well, maybe not the whole point, but a decent chunk of it. Laughing
From DATETIME.8xp
Code:
:If L5(2)=1
:"January→Str1
:If L5(2)=2
:"February→Str1
:If L5(2)=3
:"March→Str1
:If L5(2)=4
:"April→Str1
:If L5(2)=5
:"May→Str1
:If L5(2)=6
:"June→Str1
:If L5(2)=7
:"July→Str1
:If L5(2)=8
:"August→Str1
:If L5(2)=9
:"September→Str1
:If L5(2)=10
:"October→Str1
:If L5(2)=11
:"November→Str1
:If L5(2)=12
:"December→Str1
:Text(0,0,Str1," ",L5(3


Can be accomplished by:

Code:
Text(0,0,sub("January   February  March     April     May       June      July      August    September October   November  December  ",10(L5(2)-1),10), L5(3


Or


Code:
{1,9,16,21,26,29,33,37,43,52,59,67,75}-->L3
L3(L5(3
Text(0,0,sub("JanuaryFebruaryMarchAprilMayJuneJulyAugustSeptemberOctoberNovemberDecember", Ans, L3(L5(3)+1)-Ans+1)+" ",L5(3
An excellent pair of suggestions, rthprog. Smile I fixed your [code] tags, by the way.
Thank you very much for the suggestions. I'll get onto that immediately. Though, I won't be posting it until I get optimizations for other programs as well. I don't like uploading single programs unless it is asked for. :D





*My programs are NEVER finished
TI_Coder wrote:
Thank you very much for the suggestions. I'll get onto that immediately. Though, I won't be posting it until I get optimizations for other programs as well. I don't like uploading single programs unless it is asked for. Very Happy
You have a rather large number of programs in that zip, so is there any particular program that you'd like us to look at first that you feel may be less optimized than the others?
Here are the programs I would love to be reviewed by yourselves:

FOIL
QUADFACT
BETTING
DATETIME (84+SE)
GUESSING
PAZAAK
STIKFITE

If you could run these over and over, testing different variables and such, then post your feedback, I'd much appreciate it :D





*My programs are NEVER finished
I am very glad to say that I have just finished a little project of mine; BINCLOCK. This little (about 3kb) prgm displays the time in 8-bit using a cool little interface. Inspired by Bwana's Clock...

Here is one optimization (not really) that I just did. The first one shows how it ran with just a list of Pxl-Off commands. The second, after I assigned Pxl-Off commands according to the actual time...

Before:
http://www.freeimagehosting.net/image.php?dabb43cb98.gif

After:
http://www.freeimagehosting.net/image.php?e5ef57efba.gif





*My programs are NEVER finished
That looks great! Is it just me or does the second one look slower?


There are two types of people in the world: those who can extrapolate data from incomplete data

Code:
PROGRAM:ANGLPOLY
Input "Sides?",X
180/X{X-2,2


Code:
PROGRAM:B
FnOff
ClrDraw
GridOff
AxesOff
PlotsOff
ZStandard
84→Xmin
52→Ymin
ZInteger
94
For(A,1,0,-1
For(B,0,62
Line(B,0,Ans,B,A
Line(Ans-B,0,0,B,A
Line(B,62,Ans,62-B,A
Line(Ans-B,62,0,62-B,A
End
End


Code:
PROGRAM:BMI
Input "Feet:",F
Input "Inches:",I
Input "Weight:",W
703W/(12F+I)²
Disp "BMI:",Ans
If 1≥abs(.4Ans-9
Then
Disp "Normal
Else
If Ans<20
Then:"Under
Else:"Over
End
Disp Ans+"weight
End


Code:
PROGRAM:BOUNCER
FnOff
ClrDraw
GridOff
AxesOff
PlotsOff
15→A:1→C
35→B:1→D
While 1
Pxl-Change(A,B
A+C→A:C-2((Ans=62)-not(Ans→C
B+D→B:D-2((Ans=94)-not(Ans→D
End


Code:
PROGRAM:DATETIME
http://tibasicdev.wikidot.com/time-and-date


Code:
PROGRAM:FINALGRD
Input "Current Grade:",A
Input "Desired Grade:",B
Disp "Final Score Req.",5B-4A
Disp "Grade Achievable",.8A+20


Code:
PROGRAM:FOIL
Prompt A,B,C
A{1,B+C,BC


Code:
PROGRAM:GUESSING
Input "From:",A
Input "To:",B
randInt(A,B→A
DelVar BRepeat A=C
Input "Guess:",C
"Higher
If A<C
"Lower
If A≠C
Disp Ans
B+1→B
End
Disp "You win!","Guesses:",Ans


Code:
PROGRAM:LINEINFO
Input "x1:",A
Input "y1:",B
Input "x2:",C
Input "y2:",D
Disp "Slope:",(B-D)/(A-C
Disp "Distance:",R►Pr(A-C,B-D
Disp "Midpoint:",.5{A+C,B+D


Code:
PROGRAM:PYTHTHRM
Prompt A,B,C
√(C²-R►Pr(A,B)²e^(πinot(C


Code:
PROGRAM:QUADFACT
Prompt A,B,C
Pause -2C/(B+{1,-1}√(B²+4ACi²
B²/4
{A,B,Ans,Ans-C


Code:
PROGRAM:SIMPRAD
Input A
For(B,2,A
√(A/B
If fPart(Ans
End
{Ans,B


Code:
PROGRAM:SUMSQNCE
0→N:Menu("Type of Sequence","Arithmetic",0,"Geometric",1
Lbl 1:1:Lbl 0
Prompt A,B
If Ans
Disp "'0' for infinity
Prompt C
If Ans
Then
B/A→R
If C
1+log(abs(C/A))/log(abs(Ans→N
A/(1-R
If C
Ans(1-R^N
Else
B-A→R
1+Ansֿ¹(C-A→N
.5Ans(A+C
End
Disp "Number of Terms:",N
Disp "Common Ratio:",R►Frac
Disp "Sum of Terms:",Ans►Frac


Code:
PROGRAM:BINCLOCK
ClrHome
Repeat getKey
.1getTime
augment(int(Ans),10fPart(Ans→T
startTmr
Repeat checkTmr(Ans
End
For(A,1,6
Output(A,1,int(2fPart(.5^{1,2,3,4}L_T(int(.5A+2+(-1)^A
End
End

Whew, that was an all-nighter. Razz
Common Errors in English · How To Ask Questions The Smart Way
Weregoose wrote:


Code:
PROGRAM:PYTHTHRM
Prompt A,B,C
√(C²-R►Pr(A,B)²e^(πinot(C

Whew, that was an all-nighter. Razz


Hmm, couldn't get this to work: is "πinot(C"= "pie * i* not(C"?

At any rate, here's another way to do it.

Code:
:Prompt A,B,C
:C²-B²-A²
:√(Ans-2Ansnot(C
e is Napier's constant.
Common Errors in English · How To Ask Questions The Smart Way
Wow. Thank you, both of you so much. I guess I know what I'll be doing today haha





*My programs are NEVER finished
Weregoose, that's amazingly impressive! Many kudos for your dedication in going through all of those. When I was reading through all that code I thought it was TI_Coder's work, and I was very surprised that I was finding zero optimizations to make. Not so surprised anymore. Wink
Well thanks again for the optimizations, Weregoose. I'm working on all the programs one by one, including your optimizations





*My programs are NEVER finished
TI_Coder wrote:
Well thanks again for the optimizations, Weregoose. I'm working on all the programs one by one, including your optimizations
Make sure that you completely understand all the optimizations and how they work, though, and ask questions if you don't!
So far I have been understanding them completely. And that dayofweek( command made me cry (realizing I didn't have to write all that code to find it)





*My programs are NEVER finished
TI_Coder wrote:
So far I have been understanding them completely. And that dayofweek( command made me cry (realizing I didn't have to write all that code to find it)
Aww, sorry to hear it; sadly, I've been there before. Sad Not with that particular function, but with re-inventing the wheel and discovering that functions and libraries to do what I wanted had already existed.
Right? Although I have had to "re-invent the wheel" a couple times. If you hadn't noticed, I have a custom, fully coded menu for all prgms which I developed and perfected. And I also developed a prgm which prompts for number input, that way I don't have to use the dinosaur way of asking for numbers using the built-in "Input" command. This way my programs are all consistent. (and I think they look fantastic)





*My programs are NEVER finished
Well, that's fair. Actually, I made a similar program for integer input for a similar purpose (http://www.ticalc.org/archives/files/fileinfo/298/29862.html), and I made several of my programs have custom graphscreen or homescreen menus. Smile That's for style; I don't think that really counts as re-inventing the wheel. It's more inventing a sleeker, faster, less prone-to-breaking wheel.
  
Register to Join the Conversation
Have your own thoughts to add to this or any other topic? Want to ask a question, offer a suggestion, share your own programs and projects, upload a file to the file archives, get help with calculator and computer programming, or simply chat with like-minded coders and tech and calculator enthusiasts via the site-wide AJAX SAX widget? Registration for a free Cemetech account only takes a minute.

» Go to Registration page
My TI-BASIC programs
» Goto page Previous  1, 2, 3, 4, 5, 6  Next
» View previous topic :: View next topic  
Page 2 of 6
» All times are UTC - 5 Hours
 
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum

 

Advertisement